Документация к Universal RipSoft Quest©

1. Вначале отбрасываются комментарии (символы после служебного знака ";").
2. Строка разбивается на части служебным знаком "&" и для каждой части выполняются следующие операции.

   Исключение: если встречается оператор "if", то последующая за ним строка на предмет "&" не обрабатывается, эти операторы будут обрабатываться как "then" часть.

3. В выводе информации на экран сочетание символов "#$" заменяется на пробел. Сочетания "#<имя числовой переменной>$" заменяется на их целое значение без дробной части. Сочетание "#%<имя строковой переменной>$" заменяется на текст. Все сочетания символов "#/$" заменяются на перенос строки.

   Примечание: предметы инвентаря прямо не выводятся на экран в позициях #$ и не участвуют в арифметических операциях. При необходимости используйте, доступную в версии 1.3, системную переменную Inv_<Target>.
   Пример:
   Mana=13.456
   InStr HeroName=Себастьян
   p #%HeroName$ чувствует,#$что сталось #Mana$ маны в#/$резерве.
   Вывод на экран: Себастьян чувствует, что осталось 13 маны в
   резерве.

4. Рассматривается первое слово (группа символов до первого пробела), если это оператор, то он выполняется. Если это не оператор печати ("p" "pln" "print" "println") или "if" и встречается символ "=", то выполняется присвоение правой части левой.

   Примечание: если это не оператор (например метка) не делается ничего.
   Исключение: комментарии ":"и метки с символом "=" недопустимы.

5. Рассматривается следующая строка и для неё выполняются аналогичные процедуры.

• Строка, начинающаяся с символа ":" есть метка. Имя метки - вся оставшаяся часть строки.

  Пример:
  :VampireHit
  :Глубокая сумеречная пещера
  Исключение: метки с более чем двумя пробелами подряд, или с пробелами до или после запятой недопустимы, инструкции после метки недопустимы.

• Регистр переменных, предметов, меток и операторов никакой роли не играет. Но мы вам не рекомендуем использовать переменные и предметы инвентаря с пробелами.

  Примечание: при работе с инвентарем, если использовать разный регистр, то наименования предметов будут отображаться согласно последним изменениям, но на работу с инвентарем это никак не сказывается. "inv+ 2,Такелан & inv- такелаж", то в инвентаре будет отображаться "1шт. такелаж"

• Операторы "pause" или "end" должны идти отдельной строкой.

Список операторов и системных переменных

Теперь рассмотрим операторы:
Параметры операторов разделены запятыми, то есть в качестве параметра берется строка от пробела после оператора до запятой, не включительно, а в качестве второго параметра от запятой до конца, кроме последнего пробела.

Исключение: "if" имеет особый формат
Пример: "btn RipOsHive,войти в логово RipOs'a" создаст кнопку с переходом на локацию "RipOsHive" и надписью "войти в логово RipOs'a"

• p <строка> или print <строка> - печатают всю строку после них, заменяя символы "#<выражение>$" на значение этого выражения (см. "="), вложимость недопустима.

  Пример:
  print <строка>
  p У тебя #money+10$ монет"
  Вывод, если monye=100:
  У тебя 110 монет

• pln <строка> или println <строка> - аналогично операторам p и print, но с переводом каретки на новую строку.

  Пример:
  pln "Десять тысяч обезьян в жопу сунули банан" (с)
  println Русская самогончая (русский борзой бухаунд)#/$Выведена не для охоты ни на кого, а просто по полям поноситься, поорать. Способна унюхать за версту молодого первача. Применяется также для поиска бутылок и хозяев, спящих на необъятных сибирских просторах. Незаменима на охоте, рыбалке, в бане, гараже. Отличается от большинства других пород красным носом и огромными мешками под глазами. Уважает хозяина. Неприхотлива - где нажрется, там и спит
  Вывод:
  "Десять тысяч обезьян в жопу сунули банан" (с)
  Русская самогончая (русский борзой бухаунд)
  Выведена не для охоты ни на кого, а просто по полям поноситься, поорать. Способна унюхать за версту молодого первача. Применяется также для поиска бутылок и хозяев, спящих на необъятных сибирских просторах. Незаменима на охоте, рыбалке, в бане, гараже. Отличается от большинства других пород красным носом и огромными мешками под глазами. Уважает хозяина. Неприхотлива - где нажрется, там и спит

• cls - очищает окно, а именно текст и кнопки с выбором действий

• redraw - перерисовывает форму

• btn <локация>,<надпись> - создает кнопку для выбора вариантов действия с надписью на ней <надпись>, при клике на ней будет осуществлен переход на мульти-локацию "Common", потом (когда встретиться "end") оператор "cls" и переход на метку <локация>

  Пример:
  btn TalkToSuzukiSan,поговорить с китайцем
  btn Смерть неверным!,***НАШИХ БЬЮТ!***

• inv+ [<количество>,]<предмет> - добавляет <количество> (1 по умолчанию) предметов в инвентарь

  Пример:
  inv+ подтекшего мороженного
  Inv+ 7,типовых томов Некрономикона
  В инвентарь добавятся (или изменятся) две строки:
  1 шт. подтекшего мороженного
  7 шт. типовых томов Некрономикон
  Примечание: в отличие от "inv-" не проверяется, что кол-во предметов положительно, то есть если было 15 Рип и "inv+ -20,Рип" то станет -5 Рип.

• inv- [<количество>,]<предмет> - убавляет <количество> (1 по умолчанию) предметов из инвентаря

Примечание: в отличие от "inv+" проверяется, что кол-во предметов положительно, то есть если было 15 Рип и "inv+ -20,Рип" то станет Рип исчезнет из инвентаря. Операторы "inv+" и "inv-" дублируют более новую системную переменную Inv_<target>, введеную в версии 1.3. Вы можете использовать оба способа.

• invkill [<предмет>] - убирает из инвентаря все предметы <предмет> (вообще все предметы по умолчанию

• perkill - уничтожает все переменные

Примечание: операторы "invkill" и "perkill" полезно использовать в начале игры, чтобы избавиться от мусора.

• InStr <имя переменной>=<строковое выражение> - объявить строковую переменную

Пример:
InStr DefaultSay=Порву, как Тузик грелку!
pln Ты кричишь: "#%DefaultSay#"
Вывод:
Ты кричишь: "Порву, как Тузик грелку!"
Примечание: Строковые переменные выводятся на экран только в служебных знаках #%<строковая переменная>#.

• goto <метка> - передает управление на метку <метка>, то есть инструкции квеста выполняются с метки <метка>
• proc <метка> - передает управление на метку <метка>, то есть инструкции квеста выполняются с метки <метка>, но когда встречается "end" возвращает управление обратно. Вложимость допустима.

Примечание: помните,что операторы "goto" & "proc" не стирают старую информацию с экрана

• save - сохранение текста локации, инвентаря, переменных, кнопок выбора во внешнем файле.

• pause <время> - прекращение выполнения инструкций на <время> в миллисекундах, причем пользователь в это время может выбирать варианты с помощью кнопок выбора и квест будет работать дальше, но по истечении срока <время> выполнение квеста продолжится, одновременно двух работающих "pause" быть не может, новая затирает старую, забывает также он о паузе при нажатии кнопки действия.

Пример:
:1
pln Сигнал тревоги разнесся по коридору. Надо спешить, скоро здесь будет охрана.
btn LeftDoor,левая дверь
btn RightDoor,правая дверь
pause 3000
goto LeftDoor
end
:LeftDoor
pln Поздравляем! Вы выскочили прямо на встерчу бегущей охране...
end
:RightDoor
pln Спасены! Охрана пробегает мимо.
save
end

• play <мелодия> - проигрывает музыкальный файл <мелодия> из директории квеста, на время проигрывания квест не приостанавливается. Оператор дублирует системную переменную Music

• if <условие> then <операторы> - если <условие> выполняется, то выполняются <операторы>. Формат условия: комбинация boolean выражений и ключевых слов "not" "and" "or" (в порядке убывания приоритета), где boolean выражения либо вида <выражение><знак><выражение>, где <знак> это ">" "<" "<>" "=" ">=" "<="а выражение см. =, либо вида [<количество>] <предмет>, которое принимает TRUE если есть или больше <количество> (по умолчанию 1) <предмет>

  Пример:
  if 3 редчайших самоцвета and exp>=500 then pln Каменный круг начинает светится и потрескивать & btn portal,вступить в круг
  if HitArrow>3 or CheetCode=1 then p Вы пускаете три стрелы в цель и выигрываете турнир & if GodKiss=1 then pln Благодаря Богини вы правили долго и счастливо и умерли в один день

<переменная>=<выражение>. Значению <выражение> присваивается <переменная>, где <выражение> - комбинация + - * / , переменных.

В версии 1.32 введён новый тип переменных: строковые. Эти

• Системные переменные:
  Rnd - случайное число от 0 до 0.99999999999 меняется при каждом вызове
  Music - имя фоновой музыки вроде "104.mid" причем только Midi файлы
  Common - номер мульти-локации "Common"; при Common=0 вызов просто локации "Common", а при <>0 используются локации "common_номер"
  Image - имя файла с картинкой вроде "104.gif"
  ImageType - тип картинки: 0-bmp 1-ico 2-rle 3-wmf 4-emf 5-gif 6-jpg

  Примечание: Image и Music работает только с файлами, у которых имя состоит исключительно из цифр. Если вы хотите вновь убрать картинку, то используйте Image=0.

Все переменные - вещественные числа. Если переменная не инициализирована, то ее значение принимается равным 0.

Работа с инвентарём

При клике мышкой на строку инвентаря активизируется ниспадающее меню действий, состоящие из переменных-действий action, связанных с данным предметом. Т.е. локация Use_<TargetInv>_<action> отвечает за действия, выбранные из меню к данному предмету, где <TargetInv> - имя предмета, а <action> - пункт меню. Если <action> не назначен (используется просто Use_<TargetInv>), то по умолчанию используется пункт в меню "Осмотреть". За последнюю строку "Инвентарь" отвечает локация Use_Inv_<action>.

Системная переменная Inv_<TargetInv> дает вам возможность напрямую общаться с инвентарем. Она доступна как и для чтения, так и для записи. Где <TargetInv> - имя предмета.

Пример:
:1
Inv_монет=77
temp=Inv_монет
pln В кошельке персонажа точно #Inv_монет$ монет.
end
:Use_монет
pln Ну что ты там всё шаришь? Денег от этого не прибавится. Как было #gold#, так и останется #gold$ монет!
end
:Use_монет_выбросить
pln Вы выбрасываете все деньги! Не очень умный поступок.
invkill монет
end
:Use_Inv_Время
p Московское время #CurrentTime$.
if CurrentTime>0.00 and CurrentTime<7.00 then pln Ночь еще. Спи, суслик!
end
:Use_inv_Реклама
pln Здесь могла бы быть ваша реклама. Звоните 222-111-555
end
Вывод: После появления в инвентаре 77 предметов "монет" доступны два действия: осмотреть, выбросить. Для всегда присутствующей строки "Инвентарь" назначены действия "Время" и "Реклама".

Советы начинающим

• Разберитесь с мульти-локацией "common" - полезная штука
• Помните, что арифметические действия неприменимы к переменным инвентаря. Используйте промежуточную переменную Inv_<TargetInv>
• Продумайте хоть немного сюжет вашего квеста. Попытайтесь сначала набросать план на ближайшие 50-100 локаций. Смертность героя не должна превышать 10-15%, это значит, что его не должны убивать при каждом неправильном шаге. Не захламляйте инвентарь. Прорабатывайте характеры. Делайте логические разветвления и концовки. Пытайтесь получить удовольствие от процесса.

Типичные ошибки

Файлы OCX надо класть в директорию WINDOWS\SYSTEM либо в каталог к программе затем запустить "Regsvr32.exe Имя_Файла.OCX"

E: "COMDLG32" not correctly registred.
A: Скачайте COMDLG32.ocx

E: "MCI32" not correctly registred.
A: Скачайте MCI32.ocx

E: "MSDXM.OCX" not correctly registred
A: Скачайте MSDXM.OCX

E: Я не знаю, что случилось, но она заглючила и\или вылетела
А: Хмм, попытайтесь расслабиться и заняться чем-то другим

Часто возникающие вопросы

Q: Как нормально сделать голод в квесте?
A: Используйте локацию Common, например, так:

:Common
Сытость=Сытость-1
if Сытость<=0 then PrintLn Вы голодны!!!
if Хлеб then Сытость=Сытость+10 & Inv- Хлеб
end

Q: Я пишу "<TAB>P Начало!" , а в квесте нет ничего подобного???
A: Символы <TAB> перед и после команды (вплотную) недопустимы! Но можно писать например P<пробел><TAB>... и это будет работать.

Q: Я пишу ":ккк & p ккк" , а в квесте нет ничего подобного???
A: Команда ":<метка> &" недопустима, для меток надо отдельные строки.

Q: Я пишу "save & p ккк" , а в сохранении нет ничего подобного???
A: Сохранение идёт на текущий момент а "p ккк" идёт уже после

Q: Почему вопросов и советов так мало и они такие ... ?
A: Пишите свои вопросы и советы по адресу ripos@mail.ru

Хронология версий

v1.32

- оператор println добавляет перед переносом строки пробел
- новый класс строковых пременных

v1.31

- документированы скрытые системные локации Use_<target>_<action> и переменная Inv_<target>
- исправлен баг со смещением вывода картинок

v1.3 Final Relise

- невозможны = в комментариях
- исправлен таймер на "как у Victor Korianov"
- обработка кликов на инвентарь
- фоновая музыка
- сделан механизм Мульти-Common
- включена работа с любыми звуковыми файлами поддерживаемые системой
- работа с командной строкой
- полноценная работа с нецелыми числами
- возможность постановки любых пробелов и их комбинаций с запятыми
- включена поддержка картинок (показ)
- возможность печати нескольких строк одновременно одним оператором
- убрана возможность Save на метку